The English Verb: Syntax and Semantics

Dr Peter Coxhead

Contents

A Syntactic Model for the English Verb
A Prolog Grammar
Temporal Semantic Models for the English Verb
Translation Issues
Acknowledgements

A Syntactic Model for the English Verb

English verbs can have complex structures, formed both by the use of extra words (auxiliaries and modals) and by changing endings. For example, in the sentences below, each of the sets of bold words is often considered to form a single verb, 'compound verb' or 'verb group'.[1]

He usually watches television while he is eating his dinner.

John saw them there together so Paul might have been dating her.

After the champion has been beaten, she will be retired.

One possible model for the syntax of such verbs is as follows. The verb group is considered to be composed of seven elements, the first six of which are optional.

  1. S3 -- a marker for third person singular, represented by the ending /s/.
  2. PAST -- a marker for the past tense, represented by the ending /ed/. There are only two tenses in this analysis: past and nonpast. The 'future tense' of some traditional grammars is treated as being made up from the modal verb will plus the nonpast tense.[2]
  3. MOD -- a modal verb, e.g. will, may, can.
  4. PERF -- a marker for the perfect aspect, represented by the special auxiliary have plus the ending /en/.
  5. PROG -- a marker for the progressive aspect, represented by the special auxiliary be plus the ending /ing/.
  6. PASS -- a marker for the passive voice, represented by the special auxiliary be plus the ending /en/.
  7. The verb itself.

Note that Element 1 cannot be present at the same time as either Element 2 (except for be which has the form was) or Element 3.[3]

The six optional elements will be called 'features', the verb group being regarded as composed of a verb plus its features. As each feature is optional, it may be present ('+') or absent ('-'). When the verb group is generated, elements enclosed in /.../ above must be moved after the immediately following word and joined to it.

Consider the verb groups in the example sentences above.

watches In traditional grammars, this would be described as the third person present of the verb watch. In our description we can say that watch is marked as having the features +S3, -PAST, -MOD, -PERF, -PROG, -PASS. Thus it is generated by the process:

S3 + watch --> /s/ + watch --> watch/s/ --> watches

The correct watches rather than watchs can be obtained either by a lexicographic or phonological rule about s affixing or by a dictionary look up.

is eating +S3, -PAST, -MOD, -PERF, +PROG, -PASS, i.e. the third person present progressive of eat.

S3 + PROG + eat --> /s/ + be + /ing/ + eat --> be/s/ + eat/ing/ --> is eating

The last step needs dictionary lookup to ensure that is results rather than bes.

saw -S3, +PAST, -MOD, -PERF, -PROG, -PASS, i.e. the past tense of see.

PAST + see --> /ed/ + see --> see/ed/ --> saw

might have been dating -S3, +PAST, +MOD(may), +PERF, +PROG, -PASS applied to the verb date, i.e. the conditional perfect progressive of date.

PAST + MOD(may) + PERF + PROG + date -->
/ed/ + may + have + /en/ + be + /ing/ + date -->
may/ed/ + have + be/en/ + date/ing/ -->
might have been dating

may/ed/ --> might requires a dictionary lookup; date/ing/ --> dating can be done using lexicographic rules.

has been beaten +S3, -PAST, -MOD, +PERF, -PROG, +PASS applied to beat.

S3 + PERF + PASS + beat --> /s/ + have + /en/ + be + /en/ + beat -->
have/s/ + be/en/ + beat/en/ --> has been beaten

will be retired -S3, -PAST, +MOD(will), -PERF, -PROG, +PASS applied to retire.

MOD(will) + PASS + retire --> will + be + /en/ + retire -->
will + be + retire/en/ --> will be retired

Maximum complexity would be attained by applying +PAST, +MOD (e.g. will), +PERF, +PROG, +PASS to some verb, e.g. eat:

PAST + MOD(will) + PERF + PROG + PASS + eat -->
/ed/ + will + have + /en/ + be + /ing/ + be + /en/ + eat -->
will/ed/ + have + be/en/ + be/ing/ + eat/en/ -->
would have been being eaten

However it is a little difficult to think of a sensible context in which this could be said or written!

The table below summarizes the forms of the verb eat covered by this model, using the modal will.





Form of the verb eat
PAST
MOD(will)
PERF
PROG
-PASS +PASS
-
-
-
-
eat is eaten
-
-
-
+
is eating is being eaten
-
-
+
-
has eaten has been eaten
-
-
+
+
has been eating has been being eaten
+
-
-
-
ate was eaten
+
-
-
+
was eating was being eaten
+
-
+
-
had eaten had been eaten
+
-
+
+
had been eating had been being eaten
-
+
-
-
will eat will be eaten
-
+
-
+
will be eating will be being eaten
-
+
+
-
will have eaten will have been eaten
-
+
+
+
will have been eating will have been being eaten
+
+
-
-
would eat would be eaten
+
+
-
+
would be eating would be being eaten
+
+
+
-
would have eaten would have been eaten
+
+
+
+
would have been eating would have been being eaten

Forms with be being or been being sound clumsy and are rare.

At least two further refinements are needed in a complete syntactic model.

The model can also be extended to cover non-finite forms of the verb (e.g. infinitives and /ing/ forms), negation and questions.

It is important to note that the model presented above represents only the SYNTAX of the verb. The syntactic feature +PAST, for example, may or may not correspond to the meaning 'past time'. When reporting what someone said, it is usual to add the feature +PAST to the verb the speaker actually used to reflect that fact that the speech which is being reported occurred before the report:

John is going home => he said that John was going home
John may go home early => he said that John might go home early

On the other hand, the syntactic feature +PAST, particularly when attached to modal verbs such as will, may or can, normally implies not past time but increased conditionality or 'doubtfulness'. Compare these pairs of sentences:

John may go home early versus John might go home early
He will be cross if I break his pen versus He would be cross if I broke his pen

A Prolog Grammar

It is possible to write a grammar which corresponds closely to the model presented above. However, the grammar can be written somewhat more 'neatly' if we alter the model slightly. The features S3 and PAST are first pre-processed into one of four endings:

-S3, -PAST 0
-S3, +PAST /ed/
+S3, -PAST /s/
+S3, +PAST /eds/

These endings are then passed into the generating/recognizing process. Three further endings are needed within that process: bare, /en/ and /ing/. Endings are passed forwards to be added to the next word.

Thus, has been beaten is treated as:

S3 + PERF + PASS + beat -->
/s/ + (PERF + PASS + beat) -->
have/s/ + (/en/ + PASS + beat) -->
have/s/ + be/en/ + (/en/ + beat) -->
have/s/ + be/en/ + beat/en/ -->
has been beaten

In Prolog notation, a suitable grammar is:

vgrp --> vgrp0(0) ; vgrp0(s) ; vgrp0(ed) ; vgrp0(eds).
vgrp0(Ending) --> modal(Ending), vgrp1(bare);  vgrp1(Ending).
vgrp1(Ending) --> have(Ending),  vgrp2(en);    vgrp2(Ending).
vgrp2(Ending) --> be(Ending),    vgrp3(ing);   vgrp3(Ending).
vgrp3(Ending) --> be(Ending),    verb(en);     verb(Ending).

If we set up some appropriate words, the grammar can be tested:

modal(0) --> [may].
modal(s) --> [may].
modal(ed) --> [might].
modal(eds) --> [might].
have(0) --> [have].
have(s) --> [has].
have(ed) --> [had].
have(eds) --> [had].
have(bare) --> [have].
be(0) --> [are].
be(s) --> [is].
be(ed) --> [were].
be(eds) --> [was].
be(bare) --> [be].
be(en) --> [been].
be(ing) --> [being].
verb(0) --> [eat].
verb(s) --> [eats].
verb(ed) --> [ate].
verb(eds) --> [ate].
verb(bare) --> [eat].
verb(en) --> [eaten].
verb(ing) --> [eating].

The grammar generates or accepts all of the following:

are being eaten 
are eaten 
are eating 
ate 
eat 
eats 
had been being eaten 
had been eaten 
had been eating 
had eaten 
has been being eaten 
has been eaten 
has been eating 
has eaten 
have been being eaten 
have been eaten 
have been eating 
have eaten 
is being eaten 
is eaten 
is eating 
may be being eaten 
may be eaten 
may be eating 
may eat 
may have been being eaten 
may have been eaten 
may have been eating 
may have eaten 
might be being eaten 
might be eaten 
might be eating 
might eat 
might have been being eaten 
might have been eaten 
might have been eating 
might have eaten 
was being eaten 
was eaten 
was eating 
were being eaten 
were eaten 
were eating 

Note the following points:

A more realistic grammar should explicitly incorporate the 'features' of the verb, and also allow words to be handled via a combination of dictionary lookup and morphological analysis. One approach is as follows. Using Prolog again, features can be stored in a list. The structure:

Base:FeatureList

is a convenient way of representing the combination of a 'base' verb plus a list of its features. We need to declare that ':' is an operator:

:- op(100,xfx,:).

The grammar given earlier can now be extended by the addition of the appropriate extra arguments. The grammar starts with a verb group composed of a base verb and its features, i.e. vgrp(Verb:Fs). The feature list is then unpacked step by step.

vgrp(Verb:[Past,S3|Fs]) --> {conv(Past,S3,Ending)},
                            vgrp0(Ending,Verb:Fs).
conv('-PAST','-S3',0).    % The PAST & S3 features are converted to the
conv('-PAST','+S3',s).    % appropriate verb ending outside the grammar
conv('+PAST','-S3',ed).   % itself.
conv('+PAST','+S3',eds).
vgrp0(Ending,Verb:['+MOD'(Mod)|Fs]) --> modal(Ending,Mod),
                                        vgrp1(bare,Verb:Fs).
vgrp0(Ending,Verb:['-MOD'|Fs])  -->     vgrp1(Ending,Verb:Fs).
vgrp1(Ending,Verb:['+PERF'|Fs]) --> verb(Ending,have),
                                    vgrp2(en,Verb:Fs).
vgrp1(Ending,Verb:['-PERF'|Fs]) --> vgrp2(Ending,Verb:Fs).
vgrp2(Ending,Verb:['+PROG'|Fs]) --> be(Ending),
                                    vgrp3(ing,Verb:Fs).
vgrp2(Ending,Verb:['-PROG'|Fs]) --> vgrp3(Ending,Verb:Fs).
vgrp3(Ending,Verb:['+PASS']) --> be(Ending),
                                 verb(en,Verb).
vgrp3(Ending,Verb:['-PASS']) --> verb(Ending,Verb).

Because of its exceptional properties, the auxiliary be is perhaps left as a special case and thus built into the grammar:

be(0) --> [are].
be(s) --> [is].
be(ed) --> [were].
be(eds) --> [was].
be(bare) --> [be].
be(en) --> [been].
be(ing) --> [being].

However, be is also a verb in its own right, so we can add the rule:

verb(Ending,be) --> be(Ending).[4]

Have has been treated as a normal verb already. Modals and main verbs can looked up in the lexicon, the exact word involved depending on the ending:

modal(0,Mod) --> [Word], {lookup(Word,modal,bare,Mod)}.
modal(s,Mod) --> [Word], {lookup(Word,modal,bare,Mod)}.
modal(ed,Mod) --> [Word], {lookup(Word,modal,ed,Mod)}.
modal(eds,Mod) --> [Word], {lookup(Word,modal,ed,Mod)}.
 
verb(0,Verb) --> [Word], {lookup(Word,verb,bare,Verb)}.
verb(s,Verb) --> [Word], {lookup(Word,verb,s,Verb)}.
verb(ed,Verb) --> [Word], {lookup(Word,verb,ed,Verb)}.
verb(eds,Verb) --> [Word], {lookup(Word,verb,ed,Verb)}.
verb(bare,Verb) --> [Word], {lookup(Word,verb,bare,Verb)}.
verb(en,Verb) --> [Word], {lookup(Word,verb,en,Verb)}.
verb(ing,Verb) --> [Word], {lookup(Word,verb,ing,Verb)}.

Note that once be has been separated as a special case, there are only five forms of a verb to be handled, rather than seven,[5] since for all other verbs the '0' and 'bare' endings are the same, as are the 'ed' and 'eds' endings.

The process of looking up a word in the lexicon involves several possibilities. Firstly, the word may appear in the lexicon in its own right:

lookup(Word,Type,Ending,Base) :- dict(Word,Type,Ending,Base).

Secondly, the word may be related to the base and the ending via 'regular' affixing rules. For this to work efficiently in Prolog, the predicates need to be written taking into account the direction of processing. Consider first constructing a word, given a base and an ending. Provided there is no irregular form corresponding to this combination already in the dictionary, and provided that the base is in the lexicon, we can use morphological rules to generate the word:

lookup(Word,Type,Ending,Base) :- nonvar(Ending), nonvar(Base), !,
   not dict(_,Type,Ending,Base),
   dict(Base,Type,bare,Base),
   affix(Type,Base,Ending,Word).

On the other hand, if the word is given and we need to reduce it to a base and an ending, then provided that the word is not already in the dictionary, we can use morphological rules to find the presumed base and then check that this is in the lexicon:

lookup(Word,verb,Ending,Base) :- nonvar(Word), !,
   not dict(Word,Type,_,_),
   affix(Type,Base,Ending,Word),
   dict(Base,Type,bare,Base).

(The nots can be avoided, and the code thus made more efficient by the use of a cut after the first lookup rule, but the grammar cannot then be used in certain ways, e.g. given a set of features, it cannot straightforwardly be used to generate the correct form of all the base verbs in the dictionary.)

The predicate affix/4 handles regular affixing rules. The 'en' form is regularly realized as ed rather than en.

affix(verb,Base,en,Word):- !, affix(verb,Base,ed,Word).

The simplest affixing rules can simply use append. The predicate name/2 has a symbol as its first argument and the corresponding string as its second argument. It works in either direction, but at least one argument must not be a variable. We need to consider two cases separately: unknown Word and unknown Base.

affix(verb,Base,Ending,Word):- nonvar(Base), nonvar(Ending), !,
   name(Base,BaseString),
   name(Ending,EndingString),
   append(BaseString,EndingString,WordString),
   name(Word,WordString).
affix(verb,Base,Ending,Word):- nonvar(Word), nonvar(Ending), !,
   name(Word,WordString),
   name(Ending,EndingString),
   append(BaseString,EndingString,WordString),
   name(Base,BaseString).

More realistic affixing rules would handle such features of English lexicography as the deletion of an e when adding /ed/ or /ing/: e.g. smile + /ed/ --> smiled.

Finally we need a lexicon. Entries will have the format: dict(Word,Type,Ending,Base).

dict(may,modal,bare,may).
dict(might,modal,ed,may).
dict(have,verb,bare,have).
dict(has,verb,s,have).
dict(had,verb,ed,have).
dict(had,verb,en,have).
dict(having,verb,ing,have).
dict(eat,verb,bare,eat).
dict(ate,verb,ed,eat).
dict(eaten,verb,en,eat).

Note that eats and eating will be generated via the affixing rules. Paradoxically, in modern English, the ending here described as /en/ is only exceptionally realized as en.

Testing the Prolog code yields, for example:

?- vgrp(V,[was,eating],[]).
V = eat:[+PAST,+S3,-MOD,-PERF,+PROG,-PASS]
 
?- vgrp(eat:['-PAST','+S3','+MOD'(may),'+PERF','-PROG','+PASS'],S,[]).
S = [may,have,been,eaten]

Temporal Semantic Models for the English Verb

The passive will be ignored in this discussion, since adding +PASS does not alter the temporal semantics of an English verb.

Present Tenses

Semantic models are always to some degree approximate, and are subject to many exceptions. Nevertheless, in many cases, English verbs conform well to the temporal model shown in the diagram for four forms of the verb eat.

The 'simple present' form -PAST, -MOD, -PERF, -PROG (eat or eats) has no specific temporal reference point. It is not specifically past, nor specifically future, nor specifically linked to the reference point 'now'. Thus it can be used in sentences with vague or general time references, such as:

Sometimes, I eat fish.
She generally eats fish.
When he eats fish, it makes him ill.

Even when there is an apparently specific time reference, it must be interpreted more generally. Compare:

At 6 o'clock I eat fish.
At 6 o'clock I was eating fish.

The simple present form in the first sentence implies that the action occurred not at one particular time, but rather 'at 6 o'clock most days'. The arrows and the question marks in the diagram are meant to indicate this lack of definite temporal reference. In fact, the only definite temporal information conveyed by the simple present is that the action is not in progress 'now'. In this sense, the English 'present' tense is better thought of as 'nonpast, nonfuture'.

Adding +PROG (i.e. -PAST, -MOD, -PERF, +PROG) gives the 'present progressive' form (e.g. is eating). This anchors the action to the reference point 'now'. Whether or not the action started in the past or will continue in the future, it is actually in progress at a specific time point. That this time point is 'now' is shown by -PAST, -MOD. Thus this form can be used in sentences like

Right now I am eating fish.
Sorry, he's eating at the moment; can he call you back?
She hates being interrupted when she's eating her dinner.

The last example makes the point that the anchoring to 'now' is not precise: the essential element is that there is a reference point (here the time at which she is eating her dinner), but that this reference point is neither definitely past nor future.

Adding +PERF (i.e. -PAST, -MOD, +PERF, -PROG) gives the 'present perfect' form (has eaten or have eaten). This anchors the action to having finished before the reference point 'now' (as shown by -PAST, -MOD). Its duration in the past is undefined. Thus:

No, I don't want anything now, I have already eaten.
She has eaten fish in the past, but doesn't like it now.
John's (=has) eaten his dinner, so he's (=is) just getting ready.

In each case, relative to 'now', the action of eating has finished or is completed. Thus in the last example, at the point 'now' John is in the process of getting ready, and the action of eating his dinner is over. Note carefully that although the action of the verb is in the past, the temporal reference point is 'now', which is why it is acceptable to say I've eaten my dinner now.

Adding +PROG and +PERF to the base form (giving -PAST, -MOD, +PERF, +PROG) gives the 'present perfect progressive' form (has been eating or have been eating). This anchors the action to having started at some time in the past and be still happening at the reference point 'now'. There is no implication that the action will continue into the future. Thus:

I've been eating this piece of bread for 10 minutes now it's so tough.
She's been eating her dinner since you rang.

In the last example, since you rang establishes a time in the past when the action of eating began; the present perfect progressive shows that the action has continued until 'now' (again a slightly vague time, but neither clearly past nor future).

Past Tenses

The entire diagram can be moved into the past by adding +PAST to the verb.

The 'simple past' form +PAST, -MOD, -PERF, -PROG (ate) has no specific temporal reference point, although the action occurred sometime in the past. Thus it can be used in sentences like:

I ate fish last year, but I don't now
When he last ate fish, it made him ill.

The arrows and the question marks in the diagram are meant to indicate this lack of a clear and precise temporal reference point. However, this is less true of the simple past than of the simple present, since it's acceptable to say At precisely 3.32 pm I ate a sandwich. (Compare *At precisely this moment, I eat a sandwich.)

The 'past progressive' form +PAST, -MOD, -PERF, +PROG (was eating or were eating) anchors the action to some reference point in the past.

Just then I was eating fish.
Sorry, he was eating at the moment you called, so he couldn't answer.
She always hated being interrupted when she was eating her dinner.

In the last example, at each point of interruption (which happened more than once in the past), the action of eating was going on at exactly that point.

The 'past perfect' form +PAST, -MOD, +PERF, -PROG (had eaten) anchors the action to having finished before a reference point in the past. The duration of the action is undefined. Thus:

I didn't want anything then, I had already eaten.
She had eaten fish before she came here.
He'd eaten his dinner when John called.

In each case, relative to some time point in the past, the action of eating has finished or is completed. Thus in the last example, at the point in the past when John called, the eating had finished.

Adding +PROG and +PERF to the past form (i.e. +PAST, -MOD, +PERF, +PROG) gives the 'past perfect progressive' form (had been eating). This anchors the action to having started some time in the past and be still happening at some reference point in the past. Thus

I'd (=had) been eating this piece of bread for 10 minutes before I threw it away.
When you rang, she had been eating her dinner since 6 o'clock.

In the last example, when you rang establishes a time in the past when the action of eating was taking place, having begun earlier still.

Future Tenses

Morphologically, English has no future tense. The future is conveyed by the modal will or shall. Here I'll ignore the difference between these two. Adding +MOD(will) moves the model forward into the future.

The 'simple future' form -PAST, +MOD(will), -PERF, -PROG (will eat) has no specific temporal reference point, although it will occur sometime in the future. Thus it can be used in sentences like

I'll eat fish one of these days, but not now.
He'll eat the fish tomorrow.

The arrows and the question marks in the diagram are meant to indicate this lack of a clear and precise temporal reference point. However, as with the 'simple past', this is less true than for the 'simple present', since it's acceptable to say Tomorrow at precisely 3.32 pm I will eat a sandwich. (Compare *At precisely this moment, I eat a sandwich.)

The 'future progressive' form -PAST, +MOD(will), -PERF, +PROG (will be eating) anchors the action to some reference point in the future.

I can't call you at 6 o'clock because I'll be eating my dinner.
Sorry, he will be eating at 6 o'clock, so he won't be able answer if you call then.

In both examples, the time 6 o'clock is in the future.

The 'future perfect' form -PAST, +MOD(will), +PERF, -PROG (will have eaten) anchors the action to having finished before a reference point in the future. The duration of the action is undefined. Thus

I won't want anything then, I'll have eaten already.
She'll have eaten her dinner before she comes here.
He will have eaten his dinner by the time John calls.

In each case, relative to some time point in the future, the action of eating will have finished or will be completed. Thus in the last example, at the point in the future when John calls, the eating will have finished. (Note that the 'present' tense in the second verb in the last two examples refers to a future time.)

Adding +PROG and +PERF as well as +MOD(will) (i.e. +PAST, +MOD(will), +PERF, +PROG) gives the 'future perfect progressive' form (will have been eating). This anchors the action to having started at some time (past, present or future) and be still happening at some reference point in the future. Thus:

I'll have been eating my dinner for 10 minutes by then.
When the film begins, she'll only have been eating her dinner for ten minutes.

In the last example, when the film rings establishes a time in the future when the action of eating will still be continuing, having already begun.

Conditional tenses

Consider the sentences:

When I come home, I'll eat the fish.
When the support breaks, the structure will fall.

Here, as noted above, the simple future form (will eat or will fall) seems to correspond to a future action without a very specific time reference. However, the modal will can express more than mere occurrence in the future. Superficially, these sentences are similar:

If I come home, I'll eat the fish.
If the support breaks, the structure will fall.[6]

The difference is that if sets up alternative scenarios; in the second sentence, for example, the support may not break, in which case the structure may or may not fall. The falling is future to the breaking, but here CAUSALLY future rather than only temporally future.

Temporally, adding both +PAST and +MOD(will) doesn't appear to make sense. However, if +MOD(will) is taken to express causality, then there is less contradiction. Adding +PAST to both verbs in the two sentences above gives:

If I came home, I would eat the fish.
If the support broke, the structure would fall.

The effect of +PAST here is not to move the action backwards in time, but to increase its uncertainty.[7] The implication is that I'm not likely to come home nor is the support likely to break. Forms with +PAST and +MOD(will) are usually called 'conditional'.

The 'simple conditional' form +PAST, +MOD(will), -PERF, -PROG (would eat) has no specific temporal reference point, once the possible state to which it relates has been set up. Thus the examples above:

If I came home, I would eat the fish.
If the support broke, the structure would fall.

The 'progressive conditional' form +PAST, +MOD(will), -PERF, +PROG (would be eating) anchors the conditional action to definite time in the possible state. The duration of the action is undefined. Thus:

If you came home at 6 o'clock, I would be eating my dinner.
If the support broke then, the structure would be falling when you were inside.

Notice that in this case the verb setting up the possible state does not have +PROG added.

The 'perfect conditional' form +PAST, +MOD(will), +PERF, -PROG (would have eaten) anchors the conditional action to having finished at a definite time in the possible state. Both verbs need +PERF added. Thus:

If you had come home then, I'd have eaten the fish already.
If the support had broken, the structure would have fallen before you were inside.

Adding +PROG and +PERF (i.e. +PAST, +MOD(will), +PERF, +PROG) gives the 'perfect progressive conditional' form (would have been eating). This anchors the action to having started at some time in the possible state and be still happening at some reference point in the future. Thus

If I had bought some fish, I'd already have been eating my dinner when you came home.
If you rang at 6 o'clock, by then, she would only have been eating her dinner for ten minutes.

The combination of +MOD and +PAST conveys a degree of uncertainty in other cases. Forms such as could or might, obtained by applying +PAST to MOD(can) and MOD(may) express politeness through their indirectness.

Can you pass me the salt?
Could you pass me the salt?

May I have the salt?
Might I have the salt?

In each case the second is less direct, less certain, and hence more polite.

Translation Issues

Verbs in different languages, even within the Indo-European family, generally differ considerably in both syntax and semantics. Sometimes a feature in English is simply missing. For example, German, although closely related to English, has no PROG feature. Translation into German can generally ignore the distinction between -PROG and +PROG. Translation from German requires a context dependent decision to be made as to the value of PROG.

Other languages make distinctions not present in English. For example, in Modern Greek, the most important distinction in the verb is 'perfective' (+PFTV) versus 'imperfective' (-PFTV). The +PFTV form has an s added at the end of the stem of the verb in the active (although the stem may then change due to phonological rules). Thus grafo is the 'imperfective present', with the basic meaning 'I write'; grapso is the 'perfective present', also with the basic meaning 'I write'. Semantically, perfective forms are used where the action is thought of as complete in itself, imperfective forms where the action is thought of as incomplete or extended over time. In the past tense, the imperfective often corresponds to the English I used to ... Thus, I wrote a letter yesterday is likely to be translated by the +PFTV form egrapsa, whereas I wrote to my mother regularly when I lived in England would usually be translated using the -PFTV form egrafa. In the active (i.e. with the feature -PASS), Greek has the forms shown in the table below.





Form of the verb write
PAST
FUT
PERF
PFTV
-PASS
-
-
-
-
grafo
-
-
-
+
grapso
-
-
+
±
eho grapsi
+
-
-
-
egrafa
+
-
-
+
egrapsa
+
-
+
±
iha grapsi
-
+
-
-
tha grafo
-
+
-
+
tha grapso
-
+
+
±
tha eho grapsei
+
+
-
-
tha egrafa
+
+
-
+
tha egrapsa
+
+
+
±
tha iha grapsi

Mapping these to English is difficult, and involves careful consideration of semantics. For example, either of egrafa and egrapsa may correspond to I wrote, I was writing, I had been writing and even I have written depending on the context.

Acknowledgements

The analysis presented here is based on a number of sources. These include

Baker - Syntax of English
Huddleston, R.D. (1976) An Introduction to English Transformational Syntax, Longman.
Mackridge, P. (1985). The Modern Greek Language. Oxford University Press.
Radford, A. (1997) Syntactic Theory and the Structure of English, Cambridge University Press.
?? -- The English Verb

Footnotes

[1] I am explicitly not adopting here the analysis which interprets Paul might have been dating her as Paul (might (have (been (dating her)))). Rather this sentence is treated as Paul ((might have been dating) her).

[2] Note carefully that 'past tense' here is a syntactic not a semantic category; this is discussed further below.

[3] Except for some unusual 'semi-modals' such as dare.

[4] Like many other verbs, be cannot occur with the feature +PASS. The grammar does not account for this.

[5] There would be eight if we include the S1 feature, since be has the form am.

[6] In modern English the verb in the if clause is normally ±PAST, -MOD(will), ±PROG. In earlier English, the verb would have been +SUBJ (for subjunctive). Traces remain; the past subjunctive is shown by the use of were where otherwise was would be found; e.g. I wouldn't do that if I were you (rather than if I was you) or If the support were broken, the structure would fall. The present subjunctive is now only found in quotations, e.g. If music be the food of love, play on.

[7] It's as though the forces of +PAST and +MOD(will) acting in opposite directions push the event off the time line altogether into some non-existent state of potentiality.

GoNLPA Page